O'Reilly logo

VBScript in a Nutshell, 2nd Edition by Ron Petrusha, Matt Childs, Paul Lomax

Stay ahead with the world's most comprehensive technology and business learning platform.

With Safari, you learn the way you learn best. Get unlimited access to videos, live online training, learning paths, books, tutorials, and more.

Start Free Trial

No credit card required

Name

Right, RightB Functions

Syntax

Right(string, length)
string

Use: Required

Data Type: String

The string to be processed.

length

Use: Required

Data Type: Long

The number of characters to return from the right of the string.

Return Value

A String.

Description

Returns a string containing the right-most length characters of string.

Rules at a Glance

  • If length is 0, a zero-length string (” “) is returned.

  • If length is greater than the length of string, string is returned.

  • If length is less than zero or is Null, an error is generated.

  • If string contains a Null, Right returns Null.

Example

The following function assumes it’s passed either a filename or a complete path and filename, and returns the filename from the end of the string:

Private Function ParseFileName(strFullPath)

Dim lngPos, lngStart
Dim strFilename

lngStart = 1
Do
   lngPos = InStr(lngStart, strFullPath, "\")
   If lngPos = 0 Then
      strFilename = Right(strFullPath, Len(strFullPath) - lngStart + 1)
   Else
      lngStart = lngPos + 1
   End If
Loop While lngPos > 0

ParseFileName = strFilename

End Function

Programming Tips and Gotchas

  • Use the Len function to determine the total length of string.

  • When you use the RightB function with byte data, length specifies the number of bytes to return.

VB/VBA Differences

Because VBScript doesn’t support strong typing, it does not support the Right$ and RightB$ functions, which explicitly return a data type.

With Safari, you learn the way you learn best. Get unlimited access to videos, live online training, learning paths, books, interactive tutorials, and more.

Start Free Trial

No credit card required