XML in a Nutshell, 3rd Edition

EBNF Grammar for XML 1.0 (Third Edition)

Document

[1] document ::= prolog ²² element ³⁹ Misc ²⁷ *

Character range

[2] Char ::= #x9 | #xA | #xD | [#x21-#xD7FF] | [#xE000-#xFFFD] | [#x10000-#x10FFFF] /* any Unicode character, excluding the surrogate blocks, FFFE, and FFFF. */

Whitespace

[3] S ::= (#x20 | #x9 | #xD | #xA)+

Names and tokens

[4] NameChar ::= Letter ⁸⁴ | Digit ⁸⁸ | '.' | '-' | '_' | ':' | CombiningChar ⁸⁷ | Extender ⁸⁹

[5] Name ::= ( Letter ⁸⁴ | '_' | ':') ( NameChar ⁴ )*

[6] Names ::= Name ⁵ (#x20 Name ⁵ )*

[7] Nmtoken ::= ( NameChar ⁴ )+

[8] Nmtokens ::= Nmtoken ⁷ (#x20 Nmtoken ⁷ )*

Literals

[9] EntityValue ::= '"' ([^%&"] | PEReference ⁶⁹ | Reference ⁶⁷ )* '"' | "'" ([^%&'] | PEReference ⁶⁹ | Reference ⁶⁷ )* "'"

[10] AttValue ::= '"' ([^<&"] | Reference ⁶⁷ )* '"' | "'" ([^<&'] | Reference ⁶⁷ )* "'"

[11] SystemLiteral ::= ('"' [^"]* '"') | ("'" [^']* "'")

[12] PubidLiteral ::= '"' PubidChar ¹³ * '"' | "'" ( PubidChar ¹³ - "'")* "'"

[13] PubidChar ::= #x20 | #xD | #xA | [a-zA-Z0-9] | [-'( )+,./:=?;!*#@$_%]

Character data

[14] CharData ::= [^<&]* - ([^<&]* ']]>' [^<&]*)

Comments

[15] Comment ::= '<!--' (( Char ² - '-') | ('-' ( Char ² - '-')))* '-->'

Processing instructions

[16] PI ::= '<?' PITarget ¹⁷ ( S( Char ² * - ( Char ² * '?>' Char ² *)))? '?>'

[17] PITarget ::= Name ⁵ - (('X' | 'x') ('M' | 'm') ('L' | 'l'))

CDATA sections

[18] CDSect ::= CDStart ¹⁹ CData ²⁰ CDEnd ²¹

[19] CDStart ::= '<![CDATA['

[20] CData ::= ( Char ² * - ( Char ² * ']]>' Char ² *))

[21] CDEnd ::= ']]>'

Prolog

[22] prolog ...