Writing GNU Emacs Extensions

Parsing the Buffer

Here is a definition for crossword-parse-buffer:

(defun crossword-parse-buffer ()
  "Parse the crossword grid in the current buffer."
  (save-excursion
    (goto-char (point-min))
    (let* ((line (crossword-parse-line))
           (size (length line))
           (result (make-crossword size))
           (row 1))
      (crossword--handle-parsed-line line 0 result)
      (while (< row size)
        (forward-line 1)
        (setq line (crossword-parse-line))
        (if (not (= (length line) size))
            (error "Rows vary in length"))
        (crossword--handle-parsed-line line row result)
        (setq row (+ row 1)))
      result)))

It calls crossword-parse-line, which parses a line of text and returns it in list form. The length of that list gives us the horizontal and vertical size of the crossword grid (remember, our crossword grids are always square). We then call crossword-parse-line on the size — 1 remaining lines. Each time we parse a line, we fill in a row of the crossword data structure held in result by calling crossword--handle-parsed-line, which we can define like this:

(defun crossword--handle-parsed-line (line row grid)
  "Take LINE and put it in ROW of GRID."
  (let ((column 0))
    (while line
      (cond ((eq (car line) 'block)
             (crossword-store-block grid row column))
            ((eq (car line) nil)
             (crossword-clear-cell grid row column))
            ((numberp (car line))
             (crossword-store-letter grid row column (car line))))
      (setq line (cdr line))
      (setq column (+ column 1)))))

Here's crossword-parse-line, which does the real work of crossword-parse-buffer:

(defun crossword-parse-line () "Parse ...