VBScript in a Nutshell

Name

Right, RightB Functions

Syntax

Right(string, length)

string

Use: Required

Data Subtype: String

The string to be processed.

length

Use: Required

Data Subtype: Long

The number of characters to return from the right of the string.

Return Value

A Variant of subtype String.

Description

Returns a string containing the rightmost length characters of string.

Rules at a Glance

• If length is 0, a zero-length string (“”) is returned.

• If length is greater than the length of string, string is returned.

• If length is less than zero or is Null, an error is generated.

• If string contains a Null, Right returns Null.

Example

The following function assumes it’s passed either a filename or a complete path and filename, and returns the filename from the end of the string:

Private Function ParseFileName(strFullPath)

Dim lngPos, lngStart
Dim strFilename

lngStart = 1
Do
   lngPos = InStr(lngStart, strFullPath, "\")
   If lngPos = 0 Then
      strFilename = Right(strFullPath, Len(strFullPath) - lngStart + 1)
   Else
      lngStart = lngPos + 1
   End If
Loop While lngPos > 0

ParseFileName = strFilename

End Function

Programming Tips & Gotchas

• Use the Len function to determine the total length of string.

• When you use the RightB function with byte data, length specifies the number of bytes to return.

VB/VBA Differences

Because VBScript doesn’t support strong typing, it does not support the Right$ and RightB$ functions, which explicitly return a datatype.

See Also

Len, LenB Functions, Left, LeftB Functions