Exploring Expect

Matching Multiple Times

Many tasks require an expect to be repeated some number of times. Reading files from a list is an example of this. In the example on page 133, I matched a single line with the command:

expect "(\[^\r]*)\r\n"

This can be wrapped in a loop to read multiple lines and break when a prompt appears:

while 1 {
    expect {
        "(\[^\r]*)\r\n"   process_line
        $prompt   break
    }
}

This version has additional patterns upon which to break out of the loop:

while 1 {
    expect {
        "(\[^\r]*)\r\n" process_line
        eof {
            handle_eof
            break
        }
        timeout {
            handle_timeout
            break
        }
        $prompt break
    }
}

Here, handle_eof and handle_timeout are imaginary procedures that perform some processing appropriate to the condition. More importantly, notice that all of the patterns but one terminate by breaking out of the loop. It is possible to simplify this by using the exp_continue command.

When executed as an expect action, the command exp_continue causes control to be continued inside the current expect command. expect continues trying to match the pattern, but from where it left off after the previous match. expect effectively repeats its search as if it had been invoked again.

Since expect does not have to be explicitly reinvoked, the while command is not necessary. The previous example can thus be rewritten as:

expect {
    "(\[^\r]*)\r" {
        process_line
        exp_continue
    }
    eof handle_eof
    timeout handle_timeout
    $prompt
}

In this example, each line is matched and then processed via process_line. expect then continues to search ...