Beginning AppleScript®

A.7. Chapter 7

A.7.1. Exercise 1 solution

info for (path to documents folder)

A.7.2. Exercise 2 solution

set infoApp to info for (path to application "Script Editor")
short version of infoApp

A.7.3. Exercise 3 solution

-- Implement a simplified "Get info" command

set theFile to choose file default location (path to home folder)

set infoRec to info for theFile

set theResult to "Info for " & (theFile as string) & return & return
set theResult to theResult & "Size (bytes):  " & (size of infoRec as integer) & ¬
          return
set theResult to theResult & "Created:  " & (creation date of infoRec as string) ¬
       & return
set theResult to theResult & "Last Modified: " & (modification date of infoRec ¬
          as string) & return
set theResult to theResult & "File Extension: " & (file extension of infoRec) & ¬
          return
set theResult to theResult & "Alias: "

if alias of infoRec is true then
    set theResult to theResult & " Yes"
else
    set theResult to theResult & " No"
end if


display dialog theResult buttons {"OK"} default button 1

A.7.4. Exercise 4 solution

-- Sum the size of the files in the Documents folder

set folderPath to (path to documents folder) as string
set fileList to list folder folderPath

set totalSize to 0

repeat with aFile in fileList
    set theFile to contents of aFile
    set infoRec to info for file (folderPath & theFile)
    set totalSize to totalSize + (size of infoRec)
end repeat

display dialog "Your files in " & folderPath & " take up " & (totalSize as ¬
    string) & " bytes"

A.7.5. Exercise 5 solution ...