Programming Perl, 4th Edition

Hashes

As we said earlier, a hash is just a funny kind of array in which you look values up using key strings instead of numbers. A hash defines associations between keys and values, so hashes are often called associative arrays by people who are not lazy typists.

There really isn’t any such thing as a hash literal in Perl, but if you assign an ordinary list to a hash, each pair of values in the list will be taken to indicate one key/value association:

my %map = ("red",0xff0000,"green",0x00ff00,"blue",0x0000ff);

This has the same effect as:

my %map;        # an uninitialized hash is born empty
$map{red}   = 0xff0000;
$map{green} = 0x00ff00;
$map{blue}  = 0x0000ff;

It is often more readable to use the => operator between key/value pairs. The => operator is just a synonym for a comma, but it’s more visually distinctive and also quotes any bare identifiers to the left of it (just like the identifiers in braces above), which makes it convenient for several sorts of operations, including initializing hash variables:

my %map = (
    red   => 0xff0000,
    green => 0x00ff00,
    blue  => 0x0000ff,
);

or initializing anonymous hash references to be used as records:

my $rec = {
    NAME  => "John Smith",
    RANK  => "Captain",
    SERNO => "951413",
};

or using named parameters to invoke complicated functions:

my $field = radio_group(
    NAME      => "animals",
    VALUES    => ["camel", "llama", "ram", "wolf"],
    DEFAULT   => "camel",
    LINEBREAK => "true",
    LABELS    => \%animal_names,
);

But we’re getting ahead of ourselves again. Back to hashes.

You can use ...